77 lines
1.9 KiB
Bash
77 lines
1.9 KiB
Bash
|
# Maintainer: Danct12 <danct12@disroot.org>
|
||
|
|
pkgname=phosh
|
||
|
|
pkgver=0.40.0
|
||
|
|
pkgrel=1
|
||
|
|
pkgdesc="A Wayland shell for GNOME on mobile devices."
|
||
|
|
arch=('x86_64' 'armv7h' 'aarch64')
|
||
|
|
url="https://gitlab.gnome.org/World/Phosh/phosh"
|
||
|
|
license=('GPL-3.0-or-later')
|
||
|
|
depends=(
|
||
|
|
'callaudiod'
|
||
|
|
'evince'
|
||
|
|
'evolution-data-server'
|
||
|
|
'feedbackd'
|
||
|
|
'gcr'
|
||
|
|
'gtk3'
|
||
|
|
'libadwaita'
|
||
|
|
'libcap'
|
||
|
|
'libgmobile'
|
||
|
|
'libhandy'
|
||
|
|
'libnm'
|
||
|
|
'libpulse'
|
||
|
|
'gnome-desktop'
|
||
|
|
'gnome-session'
|
||
|
|
'gnome-shell'
|
||
|
|
'phoc'
|
||
|
|
'squeekboard'
|
||
|
|
'upower'
|
||
|
|
)
|
||
|
|
makedepends=(
|
||
|
|
'gi-docgen'
|
||
|
|
'glib2-devel'
|
||
|
|
'meson'
|
||
|
|
'python-docutils'
|
||
|
|
'python-packaging'
|
||
|
|
'wayland-protocols'
|
||
|
|
)
|
||
|
|
checkdepends=('xorg-server-xvfb')
|
||
|
|
install="$pkgname.install"
|
||
|
|
source=(https://sources.phosh.mobi/releases/$pkgname/$pkgname-$pkgver.tar.xz{,.asc}
|
||
|
|
'pam_phosh'
|
||
|
|
'phosh.service')
|
||
|
|
sha256sums=('d08895b19095a4a9fbe824700304973615936c55c0b04877f20269254d7dd640'
|
||
|
|
'SKIP'
|
||
|
|
'43b94d0d9f4d083f028c77d18cb0d0f8037d160c41f333878c7cae3df0163c3d'
|
||
|
|
'48dfe40c42218c92eec59969c06f203dc8a3928b21ca9ee2b92b0987de874a66')
|
||
|
|
validpgpkeys=('0DB3932762F78E592F6522AFBB5A2C77584122D3')
|
||
|
|
|
||
|
|
prepare() {
|
||
|
|
cd $pkgname-$pkgver
|
||
|
|
}
|
||
|
|
|
||
|
|
build() {
|
||
|
|
local meson_options=(
|
||
|
|
--libexecdir=/usr/lib/$pkgname
|
||
|
|
-D gtk_doc=true
|
||
|
|
-D man=true
|
||
|
|
-D phoc_tests=disabled
|
||
|
|
)
|
||
|
|
arch-meson $pkgname-$pkgver output "${meson_options[@]}"
|
||
|
|
meson compile -C output
|
||
|
|
}
|
||
|
|
|
||
|
|
check() {
|
||
|
|
xvfb-run meson test -C output --print-errorlogs
|
||
|
|
}
|
||
|
|
|
||
|
|
package() {
|
||
|
|
meson install -C output --destdir "$pkgdir"
|
||
|
|
|
||
|
|
install -Dm644 "$srcdir"/phosh.service \
|
||
|
|
"$pkgdir"/usr/lib/systemd/system/phosh.service
|
||
|
|
install -Dm644 "$srcdir"/pam_phosh \
|
||
|
|
"$pkgdir"/etc/pam.d/phosh
|
||
|
|
mkdir -p "$pkgdir"/usr/share/applications
|
||
|
|
ln -s sm.puri.Squeekboard.desktop "$pkgdir"/usr/share/applications/sm.puri.OSK0.desktop
|
||
|
|
}
|