c7b53c03ae
Since we clone the environments to build thirdparty code, we don't get an explicit dependency on the build objects produced by that environment. So when we update thirdparty code, Godot code using it is not necessarily rebuilt (I think it is for changed headers, but not for changed .c/.cpp files), which can lead to an invalid compilation output (linking old Godot .o files with a newer, potentially ABI breaking version of thirdparty code). This was only seen as really problematic with bullet updates (leading to crashes when rebuilding Godot after a bullet update without cleaning .o files), but it's safer to fix it everywhere, even if it's a LOT of hacky boilerplate.
48 lines
1.3 KiB
Python
48 lines
1.3 KiB
Python
#!/usr/bin/env python
|
|
|
|
Import("env")
|
|
Import("env_modules")
|
|
|
|
env_ws = env_modules.Clone()
|
|
|
|
thirdparty_obj = []
|
|
|
|
if env["platform"] == "javascript":
|
|
# Our JavaScript/C++ interface.
|
|
env.AddJSLibraries(["library_godot_websocket.js"])
|
|
|
|
elif env["builtin_wslay"]:
|
|
# Thirdparty source files
|
|
thirdparty_dir = "#thirdparty/wslay/"
|
|
thirdparty_sources = [
|
|
"wslay_net.c",
|
|
"wslay_event.c",
|
|
"wslay_queue.c",
|
|
"wslay_stack.c",
|
|
"wslay_frame.c",
|
|
]
|
|
thirdparty_sources = [thirdparty_dir + s for s in thirdparty_sources]
|
|
|
|
env_ws.Prepend(CPPPATH=[thirdparty_dir + "includes/"])
|
|
env_ws.Append(CPPDEFINES=["HAVE_CONFIG_H"])
|
|
|
|
if env["platform"] == "windows" or env["platform"] == "uwp":
|
|
env_ws.Append(CPPDEFINES=["HAVE_WINSOCK2_H"])
|
|
else:
|
|
env_ws.Append(CPPDEFINES=["HAVE_NETINET_IN_H"])
|
|
|
|
env_thirdparty = env_ws.Clone()
|
|
env_thirdparty.disable_warnings()
|
|
env_thirdparty.add_source_files(thirdparty_obj, thirdparty_sources)
|
|
env.modules_sources += thirdparty_obj
|
|
|
|
|
|
# Godot source files
|
|
|
|
module_obj = []
|
|
|
|
env_ws.add_source_files(module_obj, "*.cpp")
|
|
env.modules_sources += module_obj
|
|
|
|
# Needed to force rebuilding the module files when the thirdparty library is updated.
|
|
env.Depends(module_obj, thirdparty_obj)
|